///////////////////////////////////////////////////////////////
/*
kinedraw [simple webcam version] (2001-2004)
by andreas gysin
www.ertdfgcvb.ch
*/

///////////////////////////////////////////////////////////////
int hquads = 10;
int vquads = 10;
int quadwidth;
int quadheight;
int actualimage = 0;
int buflength = hquads * vquads + 10; //plus some extra images
BImage[] bitlist = new BImage[buflength];
boolean newFrame = false;

///////////////////////////////////////////////////////////////
void setup()
{
  size(800, 600);
  framerate(30);
  quadwidth = width / hquads; 
  quadheight = height / vquads; 
  for (int i=0; i<buflength; i++){
    bitlist[i] = new BImage(quadwidth,quadheight);
  }
  beginVideo(quadwidth, quadheight, 30);
}

///////////////////////////////////////////////////////////////
void videoEvent()
{
  newFrame = true;
  bitlist[actualimage] = video.copy();
  actualimage++;
  if (actualimage == buflength) actualimage = 0;
}

///////////////////////////////////////////////////////////////
void loop()
{
  if(newFrame) {
    newFrame = false;
    int p = actualimage;
    for (int j=0; j<vquads; j++){
      for (int i=0; i<hquads; i++){
        p--;
        if (p<0) p = buflength-1;
        image(bitlist[p],i*quadwidth, j*quadheight);
      }
    }
  }
}